OM-funktionen i Excel – så skriver du en OM-sats

Syntax: så fungerar OM

=OM(logiskt_test; värde_om_sant; [värde_om_falskt])

• logiskt_test – villkoret som testas, t.ex. B2>=50 eller C2="Ja"
• värde_om_sant – det som visas om villkoret stämmer
• värde_om_falskt – det som visas om villkoret inte stämmer (valfritt)

I villkoret kan du använda jämförelseoperatorerna =, <> (inte lika med), >, <, >= och <=.

Exempel på OM-satser

Godkänd eller underkänd

=OM(B2>=50; "Godkänd"; "Underkänd")

Räkna ut en bonus

Ge 5 % bonus om försäljningen i B2 är över 100 000 kr, annars 0:

=OM(B2>100000; B2*5%; 0)

Visa en tom cell

Vill du att cellen ska vara tom när villkoret inte stämmer skriver du två citattecken:

=OM(C2="Ja"; "Klar"; "")

Bara räkna om cellen inte är tom

=OM(A2=""; ""; A2*1,25)

Flera villkor med OCH och ELLER

Kombinera OM med OCH när alla villkor måste stämma, och med ELLER när det räcker att ett villkor stämmer.

=OM(OCH(B2>=50; C2="Ja"); "Godkänd"; "Underkänd")
=OM(ELLER(D2="Stockholm"; D2="Göteborg"); "Storstad"; "Övrigt")

Nästlade OM-satser – fler än två utfall

Behöver du fler än två utfall kan du lägga en OM-sats inuti en annan. Excel testar villkoren i tur och ordning och stannar vid det första som stämmer:

=OM(B2>=90; "A"; OM(B2>=75; "B"; OM(B2>=50; "C"; "F")))

Om ett värde finns i en kolumn

Vill du kontrollera om ett värde finns någonstans i en lista kombinerar du OM med ANTAL.OM:

=OM(ANTAL.OM(A:A; D2)>0; "Finns"; "Finns ej")

Vill du se om en cell innehåller ett visst ord kan du använda jokertecken:

=OM(ANTAL.OM(A2; "*faktura*"); "Ja"; "Nej")

Vanliga fel i OM-satser

• #NAMN? – oftast saknas citattecken runt en text, eller så är funktionsnamnet felstavat
• Fel resultat – kontrollera ordningen i nästlade OM: testa det högsta gränsvärdet först
• Talet räknas inte – talet i cellen är lagrat som text. Läs mer i Felmeddelanden i Excel