Lär dig LETARAD i Excel

LETARAD steg för steg

Funktionen LETARAD används för att söka upp ett värde (letauppvärde) i en tabellkolumn och returnera ett annat värde från en annan kolumn på samma rad. I exemplet nedan letar vi upp ett namn och returnerar födelseåret och åldern för personen.

Här ser vi en tabell med fyra kolumner: Namn, Födelseår, Ålder och Födelseort.

Vi vill ta reda på Evas födelseår och ålder.

Till höger om tabellen ska vi nu använda funktionen LETARAD för att ta reda på vilket födelseår och vilken ålder Eva har. Vi ställer oss i cell G3 och börjar skriva funktionen. Alla funktioner börjar med ett =-tecken.

• Letauppvärde: Är det värde vi ska leta efter i tabellen – i detta fall Eva, som står i cell F3. Skriver du texten direkt i formeln måste den stå inom citattecken, till exempel "Eva".
• Tabellmatris: Är tabellen vi ska söka i. Kolumnen där letauppvärdet ligger ska alltid vara den första kolumnen. Vi markerar hela tabellen, A3:D21.
• Kolumnindex: Är den kolumn som värdet vi vill hämta ligger i. Vi vill hämta födelseår och därför blir kolumnindex 2.
• Ungefärlig: Kan antingen vara SANT eller FALSKT. I 99 % av fallen ska vi skriva FALSKT. Då blir matchningen exakt.

=LETARAD(F3; $A$3:$D$21; 2; FALSKT)

Resultatet blir 1977. För att hämta åldern i H3 byter du kolumnindex till 3: =LETARAD(F3; $A$3:$D$21; 3; FALSKT) ger 45.

Syntax: så fungerar LETARAD

=LETARAD(letauppvärde; tabellmatris; kolumnindex; [ungefärlig])

• letauppvärde – det du söker efter (t.ex. ett artikelnummer i A2)
• tabellmatris – området där du söker (t.ex. Prislista!A:D)
• kolumnindex – vilken kolumn i tabellen du vill hämta (1 = första kolumnen)
• [ungefärlig] – SANT/FALSKT (eller 1/0). FALSKT = exakt match, nästan alltid rätt val

Fler exempel på LETARAD

Hämta pris från en prislista

A2 innehåller artikelnummer. Prislistan finns i D2:F200 där artikelnumret ligger i första kolumnen (D) och priset i kolumn 3 (F).

=LETARAD(A2; $D$2:$F$200; 3; FALSKT)

Hämta namn baserat på ID

KundID i A2, kundregister i H2:I500 där H är ID och I är namn (kolumn 2 i tabellen).

=LETARAD(A2; $H$2:$I$500; 2; FALSKT)

LETARAD och #SAKNAS!

När du använder LETARAD kommer du säkerligen att stöta på felmeddelandet #SAKNAS!. Det kan bero på att:

• värdet du söker efter inte finns i tabellen
• värdet är felstavat eller innehåller extra mellanslag – rensa med PUTSA
• talen är lagrade som text i den ena tabellen men som tal i den andra
• du inte har angett tabellområdet korrekt
• du har kopierat LETARAD-formeln nedåt och glömt att låsa tabellområdet med $

Du kan visa ett eget meddelande i stället för felet med funktionen OMSAKNAS:

=OMSAKNAS(LETARAD(F3; $A$3:$D$21; 2; FALSKT); "Hittades inte")

Vill du att cellen ska vara tom skriver du två citattecken: "". Läs mer i guiden Felmeddelanden i Excel.

Andra vanliga fel

Fel värde – ofta på grund av ungefärlig match

Om sista argumentet är SANT eller utelämnas gör LETARAD en ungefärlig match. Då måste tabellen vara sorterad och resultatet kan bli fel utan att du märker det. Använd FALSKT.

Du vill slå upp åt vänster

LETARAD kan bara hämta värden till höger om sökkolumnen. Behöver du slå upp åt vänster är XLETAUPP bäst.

Kolumnindex ”går sönder” när du lägger till en kolumn

LETARAD använder ett fast kolumnnummer, så formeln kan börja hämta fel kolumn om tabellen ändras.

När ska du använda XLETAUPP i stället?

I moderna Excel är XLETAUPP ofta bättre än LETARAD eftersom den kan slå upp både åt höger och vänster, är tydligare att läsa, slipper kolumnindex och har inbyggt stöd för vad som ska visas om inget hittas.